configure.ac

   1 ##   -*- autoconf -*-
   2
   3 dnl    This file is part of linux-call-router
   4 dnl    Copyright (C) 2007 Joerg Habenicht (j.habenicht@gmx.de)
   5 dnl    Copyright (C) 2008 Peter Schlaile (peter -at- schlaile.de)
   6 dnl    Copyright (C) 2010 Andreas Eversberg (jolly@eversberg.eu)
   7
   8 dnl    This program is free software; you can redistribute it and/or
   9 dnl    modify it under the terms of the GNU General Public License as
  10 dnl    published by the Free Software Foundation; either
  11 dnl    version 2 of the License, or (at your option) any later version.
  12
  13 dnl    This program is distributed in the hope that it will be useful,
  14 dnl    but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 dnl    GNU General Public License for more details.
  17
  18 dnl    You should have received a copy of the GNU General Public License
  19 dnl    along with this library; see the file COPYING.  If not, write to
  20 dnl    the Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  21 dnl    Boston, MA 02110-1301, USA.
  22
  23
  24
  25 dnl This keeps being the first instruction.
  26 dnl Change the 2nd argument if the version increases
  27 dnl 1st + 2nd argument is used for distribution package name
  28 AC_INIT(lcr, 1.11, andreas@eversberg.eu)
  29 AC_PREREQ(2.59)
  30 AC_CONFIG_SRCDIR([main.c])
  31 AM_CONFIG_HEADER(config.h)
  32
  33 # fix warnings from autoconf + automake
  34 AC_GNU_SOURCE
  35 # AC_USE_SYSTEM_EXTENSIONS
  36 AM_INIT_AUTOMAKE(lcr,1.11)
  37
  38
  39
  40 # Checks for programs.
  41 AC_PROG_CPP
  42 AC_PROG_CXX
  43 AC_PROG_CC
  44 AC_PROG_INSTALL
  45 AC_PROG_MAKE_SET
  46 dnl required, if per binary CFLAGS are used
  47 dnl AM_PROG_CC_C_O
  48
  49
  50 # site specific configs
  51 dnl enable this to have all special options on one place
  52 dnl AC_PRESERVE_HELP_ORDER
  53
  54 # check for asterisk
  55 AC_ARG_WITH([asterisk],
  56         [AS_HELP_STRING([--with-asterisk],
  57                         [compile with built-in Asterisk channel driver @<:@default=check@:>@])
  58         ],
  59         [],
  60         [with_asterisk="check"])
  61
  62 AS_IF([test "x$with_asterisk" != xno],
  63       [AC_CHECK_HEADERS([asterisk/compiler.h],
  64                         [with_asterisk="yes"],
  65                         [if test "x$with_asterisk" != xcheck ; then
  66                       AC_MSG_FAILURE(
  67                         [--with-asterisk was given, but test for header-file asterisk/compiler.h failed])
  68                      fi
  69                      ])
  70       ])
  71
  72 if test "x$with_asterisk" = "xyes"; then
  73         ast_tone_zone_sound=
  74         ast_1_8_or_higher=
  75
  76         AC_MSG_CHECKING([for struct tone_zone_sound in asterisk/indications.h])
  77         tzs_test_result=no
  78         AC_COMPILE_IFELSE([
  79                 AC_LANG_PROGRAM(
  80                         [[#include <asterisk.h>],
  81                         [#include <asterisk/linkedlists.h>],
  82                         [#include <asterisk/indications.h>]],
  83                         [[struct tone_zone_sound * ts = NULL; (void) ts->data;]])],
  84                 [tzs_test_result=yes])
  85         AC_MSG_RESULT([$tzs_test_result])
  86
  87         if test "x$tzs_test_result" = "xyes"; then
  88                 ast_tone_zone_sound=tone_zone_sound
  89         fi
  90
  91         if test "x$ast_tone_zone_sound" = "x"; then
  92                 AC_MSG_CHECKING([for struct ast_tone_zone_sound in asterisk/indications.h])
  93                 tzs_test_result=no
  94                 AC_COMPILE_IFELSE([
  95                         AC_LANG_PROGRAM(
  96                                 [[#include <asterisk.h>],
  97                                 [#include <asterisk/linkedlists.h>],
  98                                 [#include <asterisk/indications.h>]],
  99                                 [[struct ast_tone_zone_sound * ts = NULL; (void) ts->name;]])],
 100                         [tzs_test_result=yes])
 101                 AC_MSG_RESULT([$tzs_test_result])
 102
 103                 if test "x$tzs_test_result" = "xyes"; then
 104                         ast_tone_zone_sound=ast_tone_zone_sound
 105                 fi
 106         fi
 107
 108         if test "x$ast_tone_zone_sound" = "x"; then
 109                 AC_MSG_FAILURE([No ast_tone_zone_sound, confused...])
 110         fi
 111
 112         AC_MSG_CHECKING([for struct ast_party_caller in asterisk/channel.h])
 113         apc_test_result=no
 114         AC_COMPILE_IFELSE([
 115                 AC_LANG_PROGRAM(
 116                         [[#include <asterisk.h>],
 117                         [#include <asterisk/channel.h>]],
 118                         [[struct ast_party_caller * caller = NULL; (void) caller->id;]])],
 119                 [apc_test_result=yes])
 120         AC_MSG_RESULT([$apc_test_result])
 121
 122         if test "x$apc_test_result" = "xyes"; then
 123                 ast_1_8_or_higher="-DAST_1_8_OR_HIGHER"
 124         fi
 125
 126         AST_CFLAGS="-Dtone_zone_sound=$ast_tone_zone_sound $ast_1_8_or_higher"
 127
 128         AC_SUBST([AST_CFLAGS])
 129 fi
 130
 131 AM_CONDITIONAL(ENABLE_ASTERISK_CHANNEL_DRIVER, test "x$with_asterisk" == "xyes" )
 132
 133 # check for crypto
 134 AC_ARG_WITH([ssl],
 135         [AS_HELP_STRING([--with-ssl],
 136                         [compile with ssl support (libcrypto) @<:@default=check@:>@])
 137         ],
 138         [],
 139         [with_ssl=check])
 140 LIBCRYPTO=
 141 AS_IF([test "x$with_ssl" != xno],
 142       [AC_CHECK_HEADERS([openssl/rsa.h])
 143        AC_CHECK_LIB([crypto], [main],
 144                     [AC_SUBST([LIBCRYPTO], ["-lcrypto"])
 145                      AC_DEFINE([HAVE_LIBCRYPTO], [1],
 146                                [Define if you have libcrypto])
 147                     ],
 148                     [if test "x$with_ssl" != xcheck ; then
 149                       AC_MSG_FAILURE(
 150                         [--with-ssl was given, but test for libcrypto failed])
 151                      fi
 152                     ],
 153                     -lcrypto
 154                    )
 155       ]
 156      )
 157
 158 # check for gsm-bs
 159 AC_ARG_WITH([gsm-bs],
 160         [AS_HELP_STRING([--with-gsm-bs],
 161                         [compile with OpenBSC support @<:@default=no@:>@])
 162         ],
 163         [],
 164         [with_gsm_bs="check"])
 165
 166 AM_CONDITIONAL(ENABLE_GSM_BS, test "x$with_gsm_bs" == "xyes" )
 167
 168 # check for gsm-ms
 169 AC_ARG_WITH([gsm-ms],
 170         [AS_HELP_STRING([--with-gsm-ms],
 171                         [compile with Osmocom-bb support @<:@default=no@:>@])
 172         ],
 173         [],
 174         [with_gsm_ms="check"])
 175
 176 AM_CONDITIONAL(ENABLE_GSM_MS, test "x$with_gsm_ms" == "xyes" )
 177
 178 AM_CONDITIONAL(ENABLE_GSM, test "x$with_gsm_bs" == "xyes" -o "x$with_gsm_ms" == "xyes")
 179
 180 AS_IF([test "x$with_gsm_bs" == xyes -o "x$with_gsm_ms" == xyes],
 181         [AC_MSG_CHECKING(/usr/include/gsm/gsm.h)
 182         if test -e /usr/include/gsm/gsm.h; then
 183                 AC_MSG_RESULT(yes)
 184         else
 185         AC_MSG_FAILURE([You have enabled GSM, but /usr/include/gsm/gsm.h not found! Please install the lossy GSM codec. Be sure to install it in /usr/ and not in /usr/local/. You will also find a copy on http://www.linux-call-router.de.])
 186         fi
 187         ])
 188
 189 # check for ss5
 190 AC_ARG_WITH([ss5],
 191         [AS_HELP_STRING([--with-ss5],
 192                         [compile with CCITT No. 5 support @<:@default=no@:>@])
 193         ],
 194         [],
 195         [with_ss5="check"])
 196
 197 AM_CONDITIONAL(ENABLE_SS5, test "x$with_ss5" == "xyes" )
 198
 199 # Checks for libraries.
 200 AC_CHECK_LIB([m], [main])
 201 AC_CHECK_LIB([ncurses], [main])
 202 AC_CHECK_LIB([pthread], [main])
 203
 204 # Checks for header files.
 205 AC_HEADER_DIRENT
 206 AC_HEADER_STDC
 207 AC_HEADER_SYS_WAIT
 208 AC_CHECK_HEADERS([fcntl.h netinet/in.h stdlib.h string.h sys/file.h sys/ioctl.h sys/socket.h sys/time.h unistd.h ctype.h assert.h mISDNuser/mbuffer.h assert.h])
 209
 210 # Checks for typedefs, structures, and compiler characteristics.
 211 AC_HEADER_STDBOOL
 212 AC_C_CONST
 213 AC_C_INLINE
 214 AC_TYPE_PID_T
 215 AC_HEADER_TIME
 216 AC_STRUCT_TM
 217
 218 # Checks for library functions.
 219 AC_FUNC_FORK
 220 AC_PROG_GCC_TRADITIONAL
 221 AC_FUNC_LSTAT
 222 AC_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK
 223 AC_FUNC_MALLOC
 224 AC_FUNC_MEMCMP
 225 AC_TYPE_SIGNAL
 226 AC_FUNC_STRNLEN
 227 AC_FUNC_STRTOD
 228 AC_FUNC_VPRINTF
 229 AC_CHECK_FUNCS([gettimeofday memmove memset mkdir socket strcasecmp strchr strerror strncasecmp strstr strtol strtoul])
 230
 231
 232 AC_CONFIG_FILES([Makefile])
 233 AC_OUTPUT
 234
 235
 236 AS_IF([test "x$with_gsm_bs" == xyes],[AC_MSG_NOTICE( Compiled with GSM network side support )],[AC_MSG_NOTICE( Not compiled with GSM network side support)])
 237 AS_IF([test "x$with_gsm_ms" == xyes],[AC_MSG_NOTICE( Compiled with GSM mobile side support )],[AC_MSG_NOTICE( Not compiled with GSM mobile side support)])
 238 AS_IF([test "x$with_asterisk" == xyes],[AC_MSG_NOTICE( Compiled with Asterisk channel driver support )],[AC_MSG_NOTICE( Not compiled with Asterisk channel driver support)])
 239 AS_IF([test "x$with_ss5" == xyes],[AC_MSG_NOTICE( Compiled with CCITT No.5 support )],[AC_MSG_NOTICE( Not compiled with CCITT No.5 support)])
 240